Hyper Operating System(ITRON仕様OS)

Fork

Ryuz様。

これを開始する際に、少しでも処理を軽くできないかな？と考えて色々と覗いた事はありましたが結局、道を外すようになったので中断したままとなっています。
そのうちにまたチャレンジすると思いますが、暫くはこのままだと思います。
その際には、御指導をお願いします。

さて、一応私の環境下で現状動作をしている例外ハンドラの処理をUPします。
この処理は某OSのハンドラとHOS-V4aのハンドラを混在した様な処理で、おそらく無駄な処理も結構入っていると思いますが、なにしろmips系は経験値が少ないに等しいので...。

●vector.S
　　　　.section .vector_XXX,"ax"
～～略～～
__vector_XXX:
li k0, XXX
j _kernel_exc_hdr
nop
.end __vector_XXX

●例外処理ハンドラ
#include "mips_reg.h"
～～略～～
#define __K_OPT__
～～略～～
/************************************************
　 例外処理ハンドラ
************************************************/
　　　　　　　　.global _kernel_exc_hdr
　　　　　　　　.ent　　_kernel_exc_hdr
#ifdef __K_OPT__
_kernel_exc_hdr:
　　　　　　　　/* %jp{レジスタ退避}%en{register save} */
　　　　　　　　addiu　 sp, -132
　　　　　　　　sw　　　k0, 4(sp)　　　　　　　 /* 割り込み番号保存 */
/*　　　　　　　mfc0　　k0, _CP0_CAUSE　*/
　　　　　　　　mfc0　　k1, _CP0_STATUS
　　　　　　　　sw　　　k1, 128(sp)　　　　　　 /* save CP0_STATUS */
　　　　　　　　ins　　 k1, zero, 0x01, 0x0f
　　　　　　　　ori　　 k1, k1, (6 << 10)　　　 /* 割り込みレベル=6 ... 手抜き仕様 */
　　　　　　　　mfc0　　k0, _CP0_EPC
　　　　　　　　mtc0　　k1, _CP0_STATUS
　　　　　　　　sw　　　k0, 124(sp)　　　　　　 /* save EPC */
　　　　　　　　sw　　　ra, 120(sp)
　　　　　　　　sw　　　fp, 116(sp)
　　　　　　　　sw　　　t9, 112(sp)
　　　　　　　　sw　　　t8, 108(sp)
　　　　　　　　sw　　　t7, 104(sp)
　　　　　　　　sw　　　t6, 100(sp)
　　　　　　　　sw　　　t5, 96(sp)
　　　　　　　　sw　　　t4, 92(sp)
　　　　　　　　sw　　　t3, 88(sp)
　　　　　　　　sw　　　t2, 84(sp)
　　　　　　　　sw　　　t1, 80(sp)
　　　　　　　　sw　　　t0, 76(sp)
　　　　　　　　sw　　　a3, 72(sp)
　　　　　　　　sw　　　a2, 68(sp)
　　　　　　　　sw　　　a1, 64(sp)
　　　　　　　　sw　　　a0, 60(sp)
　　　　　　　　sw　　　v1, 56(sp)
　　　　　　　　sw　　　v0, 52(sp)
　　　　　　　　sw　　　at_reg, 16(sp)
　　　　　　　　mfhi　　s6
　　　　　　　　sw　　　s6, 12(sp)
　　　　　　　　mflo　　s6
　　　　　　　　sw　　　s6, 8(sp)
　　　　　　　　lw　　　a0, 4(sp)　　　　　　　 /* 割り込み番号取り出し */
　　　　　　　　la　　　k0, _kernel_ictxcb
　　　　　　　　lbu　　 k1, 0(k0)
　　　　　　　　/* %jp{多重割込み判定} */
　　　　　　　　bne　　 zero, k1, multiple_int
　　　　　　　　addiu　 k1, 1
　　　　　　　　sb　　　k1, 0(k0)
　　　　　　　　/* %jp{スタック入れ替え} */
　　　　　　　　move　　k1, sp
　　　　　　　　lw　　　sp, 4(k0)　　　　　　　 /* 割り込み用spへ切り替え */
　　　　　　　　nop
　　　　　　　　addiu　 sp, -4
　　　　　　　　sw　　　k1, 0(sp)　　　　　　　 /* 割り込み前のsp保存 */
　　　　　　　　/* %jp{割込み開始処理} */
　　　　　　　　jal　　 _kernel_sta_inh
　　　　　　　　nop
　　　　　　　　/* %jp{割込みハンドラ実行} */
　　　　　　　　jal　　 _kernel_exe_inh
　　　　　　　　nop
　　　　　　　　/* %jp{スタック復帰} */
　　　　　　　　lw　　　sp, 0(sp)　　　　　　　 /* 元のsp呼び出し */
　　　　　　　　la　　　k0, _kernel_ictxcb
　　　　　　　　sb　　　zero, 0(k0)
　　　　　　　　/* %jp{割込み終了処理} */
　　　　　　　　jal　　 _kernel_end_inh
　　　　　　　　nop
ret_exc_hdr:
　　　　　　　　lw　　　t0, 8(sp)
　　　　　　　　mtlo　　t0
　　　　　　　　lw　　　t1, 12(sp)
　　　　　　　　mthi　　t1
　　　　　　　　lw　　　at_reg, 16(sp)
　　　　　　　　lw　　　v0, 52(sp)
　　　　　　　　lw　　　v1, 56(sp)
　　　　　　　　lw　　　a0, 60(sp)
　　　　　　　　lw　　　a1, 64(sp)
　　　　　　　　lw　　　a2, 68(sp)
　　　　　　　　lw　　　a3, 72(sp)
　　　　　　　　lw　　　t0, 76(sp)
　　　　　　　　lw　　　t1, 80(sp)
　　　　　　　　lw　　　t2, 84(sp)
　　　　　　　　lw　　　t3, 88(sp)
　　　　　　　　lw　　　t4, 92(sp)
　　　　　　　　lw　　　t5, 96(sp)
　　　　　　　　lw　　　t6, 100(sp)
　　　　　　　　lw　　　t7, 104(sp)
　　　　　　　　lw　　　t8, 108(sp)
　　　　　　　　lw　　　t9, 112(sp)
　　　　　　　　lw　　　fp, 116(sp)
　　　　　　　　lw　　　ra, 120(sp)
　　　　　　　　di
　　　　　　　　ehb
　　　　　　　　lw　　　k0, 128(sp)
　　　　　　　　lw　　　k1, 124(sp)
　　　　　　　　addiu　 sp, sp, 132
　　　　　　　　mtc0　　k0, _CP0_STATUS
　　　　　　　　mtc0　　k1, _CP0_EPC
　　　　　　　　ehb
　　　　　　　　eret
　　　　　　　　nop
multiple_int:
　　　　　　　　sb　　　k1, 0(k0)
　　　　　　　　/* %jp{割込みハンドラ実行} */
　　　　　　　　jal　　 _kernel_exe_inh
　　　　　　　　nop
　　　　　　　　j　　　 ret_exc_hdr
　　　　　　　　nop
　　　　　　　　.end　　_kernel_exc_hdr
#else
～～略～～
#endif